在 Excel 中，Average函數用于求數值的平均值，它至少要有一個數值最多只能有 255 個數值；如果求文本型或邏輯值的平均值，需要用 AverageA函數。

Average函數可以與一些函數組合求平均值，如 Average + If 組合實現隔行（或指定條件）求平均值，Average + If + Int + Left + Find 組合實現求季度平均值，Average + Year 組合實現求年平均值，Average + Month 組合實現求月平均值。

一、Excel Average函數的語法

1、表達式：AVERAGE(Number1, [Number2], ...)

中文表達式：AVERAGE(數字1, [數字2], ...)

2、說明：

A、Number 可以是數字、數組、包含數字的名稱和單元格區域，至少要有一個 Number、最多只能有 255 個 Number。

B、如果 Number 為能轉為數值的文本（如 "1"），Average函數會自動把它轉換為數值；如果 Number 為不能轉為數值的文本（如 "一"或 "A"），Average函數將返回值錯誤 #VALUE!。如果引用單元格中有文本（單元格格式為文本）；它們將被忽略。如果數組有文本，能轉為數值將計入求平均值，不能轉為數值的將被忽略。如果 Number 中有錯誤值，則返回錯誤。

C、如果引用的單元格中有 0 或空值的單元格，0 將被計入求平均值，而空值不被計入求平均值。

D、如果引用單元格中有邏輯值 True 或 False，它們將被忽略；如果  Number 為數組且包含邏輯值，則 True 被轉為 1，False 被轉為 0。

E、如果要計算引用單元格中的邏輯值和單元格格式為文本的數值，需要使用 AverageA 函數。

二、Excel Average函數的使用方法及實例

（一）引用單元格區域有數字為文本的實例

1、雙擊 B1 單元格，輸入公式 =AVERAGE(A1:A3)，按回車，返回求平均值結果 7；操作過程步驟，如圖1所示：

圖1

2、A1:A3 中共有三個數值，求平均值結果為 7，說明 A1 中的 10 未被計入求平均值，A1 左上角有一個綠色小三角形，說明 A1 的單元格格式為文本，而Average函數不把格式為文本的數字計入求平均值。

（二）數組中有文本的實例

1、雙擊 A1 單元格，把公式 =AVERAGE(4,"6",8) 復制到 A1，按回車，返回求平均值結果 6；雙擊 A1，把 6 改為“一”，按回車，返回值錯誤 #VALUE!；操作過程步驟，如圖2所示：

圖2

2、公式 =AVERAGE(4,"6",8) 返回 6，說明文本 "6" 計入了求平均值；而把 "6" 改為 "一" 后，返回錯誤，說明參數中有不能轉為數值的文本，Average函數返回錯誤。

（三）引用單元格有 0 和錯誤值的實例

1、雙擊 B1 單元格，把公式 =AVERAGE(A1:A4) 復制到 B1，按回車，返回值錯誤 #VALUE!；選中 A1，把內容刪除，B1 的值變為除數為0 錯誤 #DIV/0!；再把 A2 中的內容刪除，B1 中的值變為 0；操作過程步驟，如圖3所示：

圖3

2、從上面的操作可知，當引用單元格中有錯誤值時，Average函數都返回錯誤；引用單元格中的空單元格被忽略，而 0 被計入求平均值。

（四）引用單元格或數組中有邏輯值 True 或 False 的實例

1、雙擊 A3 單元格，輸入公式 =AVERAGE(A1:A2)，按回車，返回除數為 0 錯誤 #DIV/0!；雙擊 A4，把公式 =AVERAGE(TRUE,FALSE) 復制到 A4，按回車，返回求平均值結果 0.5；操作過程步驟，如圖4所示：

圖4

2、公式 =AVERAGE(A1:A2) 與 =AVERAGE(TRUE,FALSE) 都是對 True 和 False 求平均值，但前者返回錯誤后者能返回正確的值，說明邏輯值在單元格時，Average函數把它們忽略，而作為Average函數的參數時會被計入求平均值。

三、Excel Average函數的擴展使用實例

（一）Average + If函數組合實現隔行求平均值（或按指定條件求平均值）

1、假如要分別求“女裝和男裝”銷量的平均值。雙擊 B12 單元格，把公式 =AVERAGE(IF(C$2:C$9=A12,D$2:D$9,"")) 復制到 B12，按 Ctrl + Shift + 回車，返回求平均值結果 705；把鼠標移到 B12 右下角的單元格填充柄上，鼠標變為加號后，按住左鍵，往下拖，則求出所有男裝的平均銷量；操作過程步驟，如圖5所示：

圖5

2、公式 =AVERAGE(IF(C$2:C$9=A12,D$2:D$9,"")) 說明：

A、C$2 是對列相對引用、對行絕對引用，往下拖時，C2 不會變為 C3、C4 等；C$9、D$2、D$9 與 C$2 是一個意思；而 A12 對列和行都是相對引用，A12 會變 A13；凡是在列或行前加 $ 都表示絕對引用。

B、C$2:C$9 以數組形式返回 C2 至 C9 中的所有值，則 If 的條件 C$2:C$9=A12 變為 {"女裝";"男裝";"女裝";"男裝";"女裝";"男裝";"女裝";"男裝"}="女裝"，接著，從數組中取出每一個元素與“女裝”比較，如果相等返回 True，否則返回 False；例如：第一次取出 "女裝"，它與 "女裝" 相等，因此返回 True；第二次取出 "男裝"，它不等于 "女裝"，因此返回 False；其它的以此類推，最后返回 {TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE}。

C、則 IF(C$2:C$9=A12,D$2:D$9,) 變為 IF({TRUE;FALSE;TRUE;FALSE;TRUE;FALSE;TRUE;FALSE},D$2:D$9,)，接著從 If 的條件數組中取出每一個元素，如果為 TRUE，返回 D$2:D$9 對應的元素，否則返回 ""；例如：第一次取出 TRUE，返回 D2；第二次取出 FALSE，返回 ""；最后返回 {892;"";638;"";528;"";762;""}。

D、則公式變為 =AVERAGE({892;"";638;"";528;"";762;""})，最后對數組中的元素求平均值，最后返回 705。

提示：除可用 Average + If函數實現外，也可以用AverageIf函數實現，即 =AVERAGEIF(C2:C9,A12,D2:D9)。

（二）Average + If + Int + Left + Find函數組合實現求季度平均值（每個季度不一定有三個月）

1、假如要求每個季度的平均銷量。雙擊 E2 單元格，把公式 =AVERAGE(IF((INT(LEFT(A$2:A$10,FIND("月",A$2:A$10)-1))>(3*D2-3))*(INT(LEFT(A$2:A$10,FIND("月",A$2:A$10)-1))<=v),B$2:B$10,"")) 復制到 E2，按 Ctrl + Shift + 回車，返回求平均值結果 553.67；同樣用往下拖的方法求出其它季度平均銷量，操作過程步驟，如圖6所示：

圖6

2、公式 =AVERAGE(IF((INT(LEFT(A$2:A$10,FIND("月",A$2:A$10)-1))>(3*D2-3))*(INT(LEFT(A$2:A$10,FIND("月",A$2:A$10)-1))<=3*D2),B$2:B$10,"")) 說明：

A、A$2:A$10 以數組形式返回 A2:A10 中的月份，即 {"1月";"2月";"3月";"4月";"5月";"6月";"7月";"8月";"10月"}。

B、FIND("月",A$2:A$10) 用于依次在 A2:A10 中查找“月”的位置，目的是截取出“月份”中的數字；例如：執行時,第一次從 A2:A10取出 A2，返回“月”的位置為 2；第二次取出 A3，返回“月”的位置也為 2，其它的以此類推，最后返回 {2;2;2;2;2;2;2;2;3}；則 FIND("月",A$2:A$10)-1 變為 {2;2;2;2;2;2;2;2;3}-1，接著用數組中每個元素減 1，則數組變為 {1;1;1;1;1;1;1;1;2}。

C、則 LEFT(A$2:A$10,FIND("月",A$2:A$10)-1) 變為 LEFT({"1月";"2月";"3月";"4月";"5月";"6月";"7月";"8月";"10月"},{1;1;1;1;1;1;1;1;2})，接著，從第一個數組中取出“1月”，再從第二個數組中取出與“1月”對應的位置 1，然后把“1月”從左邊截 1 位，因此返回 1，其它的以此類推，最后返回 {"1";"2";"3";"4";"5";"6";"7";"8";"10"}。

D、則 INT(LEFT(A$2:A$10,FIND("月",A$2:A$10)-1)) 變為 INT({"1";"2";"3";"4";"5";"6";"7";"8";"10"})，進一步計算把數組中的每個元素取整，最后返回 {1;2;3;4;5;6;7;8;10}。

E、D2 為 1，把它代入 3*D2-3 得 0，再把它代入 3*D2 得 3；公式變為 =AVERAGE(IF({1;2;3;4;5;6;7;8;10}>0)*({1;2;3;4;5;6;7;8;10}<=3),B$2:B$10,""))，接著，從 If 的第一個條件數組中取出每個元素 與 0 比較，如果大于 0，返回 True，否則返回 False，最后返回 {TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}；然后再從 If 的第二個條件數組中取出每一個元素與 3 比較，如果小于等于 3，返回 True，否則返回 False，最后返回 {TRUE;TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE}。

F、則公式變為 =AVERAGE(IF({TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE;TRUE}*{TRUE;TRUE;TRUE;FALSE;FALSE;FALSE;FALSE;FALSE;FALSE},B$2:B$10,""))，然后把兩個數組對應元素相乘，相乘時，True 被轉為 1，False 被轉為 0。

G、則公式變為 =AVERAGE(IF({1;1;1;0;0;0;0;0;0},B$2:B$10,""))，接著，從 If 的條件數組中取出每一個元素，如果為 True 返回B2:B10 中對應的元素，否則返回 ""；例如：第一次取出條件數組第一個元素 1，由于為 True，所以返回 567；第二次取出第二個元素 1，返回 571；其它的以此類推，最后返回 {567;571;523;"";"";"";"";"";""}。

H、則公式變為 =AVERAGE({567;571;523;"";"";"";"";"";""})，最后對數組中的元素求平均值，結果為 553.67。

（三）求年和月平均值

（1）Average + If + Year函數組合實現求年平均值

1、假如有一個2018年的銷量表，要求年平均銷量。雙擊 E2 單元格，把公式 =AVERAGE(IF(YEAR(A$2:A$362)=D2,B$2:B$362,"")) 復制到E2，按 Ctrl + Shift + 回車，返回求平均值結果 768.64；操作過程步驟，如圖7所示：

圖7

2、公式 =AVERAGE(IF(YEAR(A$2:A$362)=D2,B$2:B$362,"")) 說明：

A、YEAR(A$2:A$362) 以數組形式返回 A2:A362 中的年份，即 {2018;2018;……;2018}。

B、則 YEAR(A$2:A$362)=D2 變為 {2018;2018;……;2018}=D2，接著從數組中取出每個 2018 與 D2（即 2018）比較，由于它們都相等，所以全返回 True，即 {TRUE;TRUE;……;TRUE}。

C、則公式變 =AVERAGE(IF(TRUE;TRUE;……;TRUE},B$2:B$362,""))，接著，從條件數組中取出每一個元素，如果為真，返回 B2:B362 中對應的值，否則返回 ""；由于條件數組中全為真，因此以數組形式返回 B2:B362 中的所有值，即 {975;697;……;841}。

D、則公式變為 =AVERAGE({975;697;……;841})，最后對數組中的值求平均值，結果為 768.64。

提示：如果表格中同時有不同年份的數據，也可以用上面的公式，要求那年的平均值，只需把具體年份寫到 D2。

（2）Average + If + Month函數組合實現求月平均值

1、假如要求 1 到 12 月的平均銷量。雙擊 D4 單元格，把公式 =AVERAGE(IF(MONTH(A$2:A$362)=D4,B$2:B$362,"")) 復制到 D4，按回車，返回 1 月求平均值結果 788.71；用往下拖的方法求出剩余月份的平均銷量；操作過程步驟，如圖8所示：

圖8

2、公式 =AVERAGE(IF(MONTH(A$2:A$362)=D4,B$2:B$362,"")) 說明：

公式與求年平均值公式一樣，所不同的是 MONTH(A$2:A$362) 用于取 A2 到 A362 中日期的月份；例如：第一次取 A2 中 2018/1/1 的月份 1。